home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / EXODUSCS.DSK / PRINT SHOP UTILITY.bas < prev    next >
BASIC Source File  |  2014-09-09  |  7KB  |  109 lines
  1. 1000  LOMEM: 24576
  2. 1010  PRINT  CHR$(21)
  3. 1020  POKE 232,0: POKE 233,64: FOR AD = 16384 TO 16531: READ DA%: POKE AD,DA%: NEXT AD
  4. 1030  TEXT : HOME : VTAB 2: HTAB 6: PRINT "*** THE PRINT SHOP CAPTURE ***"
  5. 1040  PRINT " COPYRIGHT (C) 09/84 BY GENE WARNER III": PRINT : PRINT "----------------------------------------": POKE 34,5
  6. 1050  VTAB 12: HTAB 8: PRINT "PRESS [I] FOR INSTRUCTIONS                 OR [C] TO CONTINUE"
  7. 1060  PRINT : HTAB 14: PRINT "[ ] SELECT": VTAB 15: HTAB 15
  8. 1070  GOSUB 1910: IF KY$ < >"C"  AND KY$ < >"I"  THEN 1070
  9. 1080  PRINT KY$: IF KY$ = "C"  THEN 1400
  10. 1090  HOME : PRINT 
  11. 1100  PRINT "     THIS PROGRAM IS DESIGNED TO BE USEDIN CONJUNCTION WITH THE PRINT SHOP.": PRINT 
  12. 1110  PRINT "     THE PRINT SHOP'S GRAPHIC EDITOR,   THOUGH USEFULL, IS PRIMATIVE AT BEST. IT";
  13. 1120  PRINT "CAN BE QUITE DIFFICULT AND TIME         CONSUMING TO DEVELOP A GRAPHIC DESIGN   WITH IT.": PRINT 
  14. 1130  PRINT "     MOST APPLE OWNERS HAVE A LIBRARY OFPICTURES AND A GRAPHIC EDITOR, LIKE     E-Z DRAW 3.3 FROM SIRIUS SOFTWARE.": PRINT 
  15. 1140  PRINT "     THIS PROGRAM ALLOWS YOU TO CAPTURE PORTIONS OF THOSE PICTURES INTO A PRINT SHOP GRAPHIC DATA FILE."
  16. 1150  GOSUB 1880
  17. 1160  HOME : PRINT 
  18. 1170  PRINT "     THE PROGRAM WILL FIRST ASK YOU FOR THE NAME OF THE PICTURE AND THE SLOT ANDDRIVE THAT THE PICTURE IS IN. IT WILL"
  19. 1180  PRINT "THEN ASK YOU FOR THE SAME INFORMATION ONTHE PRINT SHOP GRAPHIC DATA FILE IT WILLCREATE.": PRINT 
  20. 1190  PRINT "     IT WILL THEN CLEAR THE HIRES SCREENAND ASK YOU TO INSERT THE DISK WITH THE PICTURE. AFTER YOU HAVE DONE THAT IT"
  21. 1200  PRINT "WILL LOAD THE PICTURE AND GO TO THE     SELECTION PORTION OF THE PROGRAM.": PRINT 
  22. 1210  GOSUB 1880
  23. 1220  HOME : PRINT 
  24. 1230  PRINT "     IN THIS PORTION OF THE PROGRAM YOU WILL SEE THE PICTURE YOU HAVE LOADED AND";
  25. 1240  PRINT "A SQUARE IN THE UPPER LEFT CORNER. AT   THE BOTTOM OF THE SCREEN WILL BE A MENU OF COMMANDS.": PRINT 
  26. 1250  PRINT "     IF YOU WANT TO MOVE THE SQUARE IN  LARGE STEPS JUST PRESS THE I,J,K,M KEYS TO MAKE THE MOVES. ONCE YOU ARE CLOSE TO";
  27. 1260  PRINT "THE AREA YOU WANT TO CAPTURE HOLD DOWN  THE CONTROL KEY AS YOU MOVE THE SQUARE  AROUND.": PRINT 
  28. 1270  PRINT "     ONCE YOU HAVE OUTLINED THE AREA YOUWANT TO CAPTURE WITH THE SQUARE PRESS   THE SPACE BAR AND CAPTURING WILL BEGIN."
  29. 1280  GOSUB 1880
  30. 1290  HOME : VTAB 12
  31. 1300  PRINT "*** BE PATIENT AS THERE IS A LOT OF BIT MANIPULATION GOING ON AND BASIC IS NOT  VERY FAST AT THIS. ***"
  32. 1310  GOSUB 1880
  33. 1320  HOME : PRINT 
  34. 1330  PRINT "     OUNCE THE AREA HAS BEEN CAPTURED   THE PROGRAM WILL ASK YOU TO INSERT THE"
  35. 1340  PRINT "DISK YOU WANT THE PRINT SHOP GRAPHIC    DATA FILE ON.": PRINT 
  36. 1350  PRINT "     NOW THAT THE DATA FILE HAS BEEN    SAVED THE PROGRAM WILL GO BACK TO ASKING";
  37. 1360  PRINT "FOR THE PICTURE NAME. IF YOU ARE DONE   JUST PRESS [RETURN] AND THE PROGRAM WILLEND.": PRINT : PRINT 
  38. 1370  PRINT "     HAVE FUN AND ENJOY!!!!!!": PRINT : PRINT 
  39. 1380  PRINT "     GENE WARNER III ..."
  40. 1390  GOSUB 1880
  41. 1400  HGR : TEXT : POKE 34,5
  42. 1410  HOME : VTAB 11: INPUT " INPUT FILE:";PI$
  43. 1420  IF   NOT  LEN(PI$)  THEN  TEXT : HOME : VTAB 12: HTAB 18: PRINT "BYE...": VTAB 22: CALL 979
  44. 1430 SI% = 6: VTAB 11: HTAB  LEN(PI$) +13: PRINT ",S"SI%; CHR$(8);: INPUT "";SI$: IF  VAL(SI$)  THEN SI% =  VAL(SI$)
  45. 1440 DI% = 1: VTAB 11: HTAB  LEN(PI$) +15: PRINT SI%",D"DI%; CHR$(8);: INPUT "";DI$: IF  VAL(DI$)  THEN DI% =  VAL(DI$)
  46. 1450  VTAB 11: HTAB  LEN(PI$) +18: PRINT DI%
  47. 1460  VTAB 13: INPUT "OUTPUT FILE:";PO$: IF   NOT  LEN(PO$)  THEN 1410
  48. 1470 SO% = 6: VTAB 13: HTAB  LEN(PO$) +13: PRINT ",S"SO%; CHR$(8);: INPUT "";SO$: IF  VAL(SO$)  THEN SO% =  VAL(SO$)
  49. 1480 DO% = 1: VTAB 13: HTAB  LEN(PO$) +15: PRINT SO%",D"DO%; CHR$(8);: INPUT "";DO$: IF  VAL(DO$)  THEN DO% =  VAL(DO$)
  50. 1490  VTAB 13: HTAB  LEN(PO$) +18: PRINT DO%
  51. 1500  VTAB 18: PRINT "INSERT THE DISK WITH THE INPUT FILE IN  SLOT "SI%", DRIVE "DI%"."
  52. 1510  GOSUB 1880
  53. 1520  VTAB 18: CALL 64578: HTAB 16: PRINT "LOADING....": PRINT  CHR$(4)"BLOAD "PI$",A$2000,S"SI%",D"DI%
  54. 1530  VTAB 18: CALL 64578: POKE 49239,0: POKE 49235,0: POKE 49232,0: POKE 34,20: HCOLOR= 3: SCALE= 1: ROT= 0
  55. 1540 FX = 0:FY = 0
  56. 1550  HOME : PRINT "LARGE  I    SMALL   ^I    ACCEPT <SPACE>MOVE  J K   MOVE  ^J  ^K  ABORT  <ESC>         M            ^M";
  57. 1560  POKE  -16368,0
  58. 1570  XDRAW 1 AT FX,FY
  59. 1580  IF  PEEK( -16384) <128  THEN 1580
  60. 1590 KY% =  PEEK( -16384) -128: POKE  -16368,0
  61. 1600  XDRAW 1 AT FX,FY
  62. 1610  IF KY% = 73  THEN FY = FY -8: IF FY <0  THEN FY = 0
  63. 1620  IF KY% = 74  THEN FX = FX -7: IF FX <0  THEN FX = 0
  64. 1630  IF KY% = 75  THEN FX = FX +7: IF FX >191  THEN FX = 191
  65. 1640  IF KY% = 77  THEN FY = FY +8: IF FY >107  THEN FY = 107
  66. 1650  IF KY% = 9  THEN FY = FY -1: IF FY <0  THEN FY = 0
  67. 1660  IF KY% = 10  THEN FX = FX -1: IF FX <0  THEN FX = 0
  68. 1670  IF KY% = 11  THEN FX = FX +1: IF FX >191  THEN FX = 191
  69. 1680  IF KY% = 13  THEN FY = FY +1: IF FY >107  THEN FY = 107
  70. 1690  IF KY% = 27  THEN 1400
  71. 1700  IF KY% = 32  THEN 1720
  72. 1710  GOTO 1570
  73. 1720  HOME : PRINT : HTAB 8: PRINT "CAPTURING, PLEASE WAIT...."
  74. 1730  FOR AD = 22528 TO 23103: POKE AD,0: NEXT AD
  75. 1740  FOR SY = (FY) TO (FY +51): FOR SX = (FX) TO (FX +87): XDRAW 2 AT SX,SY: NEXT SX,SY
  76. 1750 AD% = 22528:SX% = FX:SY% = FY
  77. 1760 BY% = 0:XO% = 0
  78. 1770  POKE 234,0
  79. 1780  XDRAW 2 AT SX% +XO%,SY%
  80. 1790 BY% = BY% + PEEK(234) *2 ^(7 -XO%)
  81. 1800 XO% = XO% +1: IF XO% <8  THEN 1770
  82. 1810  POKE AD%,BY%:AD% = AD% +1
  83. 1820 SX% = SX% +8: IF SX% <FX +88  THEN 1760
  84. 1830 SX% = FX:SY% = SY% +1: IF SY% <FY +52  THEN 1760
  85. 1840  TEXT : POKE 34,5: VTAB 18: CALL 64578: PRINT "INSERT THE DISK YOU WANT THE OUTPUT FILEON IN SLOT "SO%", DRIVE "DO%"."
  86. 1850  GOSUB 1880
  87. 1860  VTAB 18: CALL 64578: HTAB 16: PRINT "SAVING....": PRINT  CHR$(4)"BSAVE "PO$",A$5800,L$240,S"SO%",D"DO%
  88. 1870  GOTO 1400
  89. 1880  VTAB 24: HTAB 8: PRINT "PRESS ANY KEY TO CONTINUE:";
  90. 1890  GOSUB 1910
  91. 1900  VTAB 23: PRINT : RETURN 
  92. 1910  GET KY$
  93. 1920  REM 
  94. 1930  RETURN 
  95. 1940  DATA  2,0,6,0,145,0,45,45,45,45
  96. 1950  DATA  45,45,45,45,45,45,45,45,45,45
  97. 1960  DATA  45,45,45,45,45,45,45,45,45,45
  98. 1970  DATA  45,45,45,45,45,45,45,45,45,45
  99. 1980  DATA  45,45,45,45,45,45,45,45,45,53
  100. 1990  DATA  54,54,54,54,54,54,54,54,54,54
  101. 2000  DATA  54,54,54,54,54,54,54,54,54,54
  102. 2010  DATA  54,54,54,54,54,63,63,63,63,63
  103. 2020  DATA  63,63,63,63,63,63,63,63,63,63
  104. 2030  DATA  63,63,63,63,63,63,63,63,63,63
  105. 2040  DATA  63,63,63,63,63,63,63,63,63,63
  106. 2050  DATA  63,63,63,63,63,63,63,63,39,36
  107. 2060  DATA  36,36,36,36,36,36,36,36,36,36
  108. 2070  DATA  36,36,36,36,36,36,36,36,36,36
  109. 2080  DATA  36,36,36,36,0,5,0,255